*--------------------------------------------------------------------------------*
This is the final program file for Michael R. Pakko and Patricia S. Pollard's
article "Burgernomincs:  A Big Mac Guide to Purchasing Power Parity" in the
November/December 2003 issue of the Federal Reserve Bank of St. Louis Review.

This program is written in SAS (v8).
There are three necessary input files:
	Big Mac data - new_bigmac.csv
	PWT data     - pwt\pwt61_VARCGDP.csv
    TWEX data    - twex_ann.xls
This creates the data for Tables 1 and 2, Figures 1 through 5(top panel), 
     Shaded Insert 3 Figures and Shaded Insert 4 Figures.
*--------------------------------------------------------------------------------*;

*--------------------------------------------------------------------------------*
BIG MAC DATA         
Through April 2003   

Source:  The Economist (various issues)
	See XLS file for more documentation
	http://www.economist.com/markets/Bigmac/Index.cfm;
*--------------------------------------------------------------------------------*;
filename in "D:\economis\pollard\extras\bigmac\new_bigmac.csv";
data bigmac(drop=country_87-country_99 country_00 country_01 country_02 country_03);
length country $19.;
infile in firstobs=2 dlm="," ls=2000;
input Country $ BMLocal_86 BMDollar_86 Xrate_86 PPP_86 
		Country_87 $ BMLocal_87 BMDollar_87 Xrate_87 PPP_87 
		Country_88 $ BMLocal_88 BMDollar_88 Xrate_88 PPP_88 
		Country_89 $ BMLocal_89 BMDollar_89 Xrate_89 PPP_89 
		Country_90 $ BMLocal_90 BMDollar_90 Xrate_90 PPP_90           
		Country_91 $ BMLocal_91 BMDollar_91 Xrate_91 PPP_91 
		Country_92 $ BMLocal_92 BMDollar_92 Xrate_92 PPP_92 
		Country_93 $ BMLocal_93 BMDollar_93 Xrate_93 PPP_93 
		Country_94 $ BMLocal_94 BMDollar_94 Xrate_94 PPP_94 
		Country_95 $ BMLocal_95 BMDollar_95 Xrate_95 PPP_95 
		Country_96 $ BMLocal_96 BMDollar_96 Xrate_96 PPP_96 
		Country_97 $ BMLocal_97 BMDollar_97 Xrate_97 PPP_97 
		Country_98 $ BMLocal_98 BMDollar_98 Xrate_98 PPP_98 
		Country_99 $ BMLocal_99 BMDollar_99 Xrate_99 PPP_99 
		Country_00 $ BMLocal_00 BMDollar_00 Xrate_00 PPP_00 
		Country_01 $ BMLocal_01 BMDollar_01 Xrate_01 PPP_01 
		Country_02 $ BMLocal_02 BMDollar_02 Xrate_02 PPP_02 
		Country_03 $ BMLocal_03 BMDollar_03 Xrate_03 PPP_03;
run;

proc sort data=bigmac; by country; run;
proc transpose data=bigmac out=BM_1Col;
  by country;
run;

data BMLocal BMDollar XRate PPP;
  set BM_1Col;

  year = compress(_name_,"BMLocal_ BMDollar_ XRate_ PPP_");
  if 86<=year<=99 then year=year+1900;
  else if 0<=year<=3 then year=year+2000;

  **Remove Brazil 1986 observation**;
  if country="Brazil" and year=1986 then delete;

  **Fix Russia Exchange Rate Switch**;
  if country="Russia/Soviet Union" and year<=1998 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="Xrate" then col1=col1/1000;
  if country="Russia/Soviet Union" and year<=1998 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="BMLocal" then col1=col1/1000;
  if country="Russia/Soviet Union" and year<=1998 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="PPP" then col1=col1/1000;

  **Fix Poland Exchange Rate Switch**;
  if country="Poland" and year=1994 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="Xrate" then col1=col1/10000;
  if country="Poland" and year=1994 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="BMLocal" then col1=col1/10000;
  if country="Poland" and year=1994 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="PPP" then col1=col1/10000;

  **Fix Brazil Exchange Rate Switch**;
  if country="Brazil" and year<=1993 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="Xrate" then col1=col1/2750000;
  if country="Brazil" and year<=1993 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="BMLocal" then col1=col1/2750000;
  if country="Brazil" and year<=1993 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="PPP" then col1=col1/2750000;

  if country="Brazil" and year=1994 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="Xrate" then col1=col1/2750;
  if country="Brazil" and year=1994 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="BMLocal" then col1=col1/2750;
  if country="Brazil" and year=1994 and compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="PPP" then col1=col1/2750;

  if compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="BMLocal" then output BMLocal;
  if compress(_name_,"0 1 2 3 4 5 6 7 8 9 _")="Xrate" then output XRate;
run;

proc sort data=BMLocal; by country year; run;
proc sort data=XRate; by country year; run;

/*
**Create Excel Files Containing Big Mac Data**;
**  Separate Sheet for Each Variable        **;
proc transpose data=BMLocal out=BMLocal_Final(drop=_name_);
  var col1;
  by country;
  id year;
  idlabel year;
run;
proc export 
  data=BMLocal_Final
  outfile="d:\temp\bigmac_bmlocal.xls"
  dbms=excel2000
  replace;
run;
proc transpose data=XRate out=XRate_Final(drop=_name_);
  var col1;
  by country;
  id year;
  idlabel year;
run;
proc export 
  data=XRate_Final
  outfile="d:\temp\bigmac_xrate.xls"
  dbms=excel2000
  replace;
run; 
*/

*Create Big Mac Data Set Used in Charts and Tables**;
data charts_parta;
  merge BMLocal(rename=(col1=BMLocal) drop=_name_)
	XRate(rename=(col1=XRate) drop=_name_);
  by country year;
run;

data charts_partb(keep=year bmus);
  set BMLocal(rename=(col1=BMUS) drop=_name_ where=(country="United States"));
run;

proc sort data=charts_parta; by year; run;
proc sort data=charts_partb; by year; run;
data charts;
  merge charts_parta charts_partb;
  by year;
  yearp=year+0;
run;
data charts;
  set charts;
  *These data points come from the Dec/Jan Survey and therefore have different US Big Mac prices*;
  if country in("Greece","Peru","Philippines","Venezuela","Saudi Arabia") and
     yearp=1998 then BMUS=2.58;
  if country in("Czech. Rep.","Greece","Philippines","Turkey","Venezuela","Saudi Arabia","Colombia") and
     yearp=1999 then BMUS=2.63;
  if country in("Greece","Philippines","Turkey","Saudi Arabia","Colombia") and
     yearp=2000 then BMUS=2.44;
  if country in("Israel","Peru","Turkey","Saudi Arabia","Colombia") and
     yearp=2001 then BMUS=2.55;

  ppp=bmlocal/BMUS;
  BMDollar=BMLocal/XRate;
run;


*--------------------------------------------------------------------------------*
PENN WORLD TABLE DATA
Version 6.1          

Source: Alan Heston, Robert Summers and Bettina Aten, Penn World Table Version 6.1, 
Center for International Comparisons at the University of Pennsylvania (CICUP), 
October 2002.
*--------------------------------------------------------------------------------*
http://pwt.econ.upenn.edu/;
filename pwt "d:\economis\pollard\extras\bigmac\pwt\pwt61_VARCGDP.csv";

data pwt(drop=rgdpch rgdpl pc);
  infile pwt firstobs=2 dlm="," ls=500 pad;
  input year ccode $3. cgdp pc rgdpch rgdpl p;
run;

data pwt_us(drop=ccode);
  set pwt(where=(ccode="USA") rename=(p=p_us cgdp=cgdp_us));
run;

*----------------------------*;
* TABLE 1 and FIGURE 1       *;
*----------------------------*;
proc sort data=pwt; by year; run;
proc sort data=pwt_us; by year; run;

data ppp_pwt(keep=ccode year ppp_pwt);
  **Keep Countries in Common with Big Mac**;
  merge pwt (where=(ccode in("ARG","AUS","AUT","BEL","BRA","GBR",
               "CAN","CHL","CHN","COL","CZE","DNK",
			   "FRA","GER","GRC","NLD","HKG","HUN",
			   "IDN","IRL","ISR","ITA","JPN","MYS",			
			   "MEX","NZL","PER","PHL","POL","PRT",
			   "RUS","KOR","SAU","SGP","ZAF","ESP",
			   "SWE","CHE","TWN","THA","TUR","USA",
			   "VEN","YUG")))
 		pwt_us;
  by year;

  **PWT PPP**;
  ppp_pwt=(p/p_us)*100;

  **Common Sample with Big Mac**;
  if year=2000;
run;

data ppp_bm;
  set charts(keep=yearp country xrate ppp);

  **Big Mac PPP**;
  ppp_bm =(ppp/xrate)*100;
  
  **Create Country Codes to Match with PWT**;
  %macro ccode(country=,ccode=);
  %do i = 1 %to 45;
  %let c=%scan(&country,&i,"~");
  %let cc=%scan(&ccode,&i);
    if country="&c" then ccode="&cc";
  %end;
  %mend;
  %ccode(country=Argentina~Australia~Austria~Belgium~Brazil~Britain~
                 Canada~Chile~China~Colombia~Czech. Rep.~Denmark~
				 France~Germany/W. Germany~Greece~Holland~Hong Kong~Hungary~
				 Indonesia~Ireland~Israel~Italy~Japan~Malaysia~
				 Mexico~New Zealand~Peru~Philippines~Poland~Portugal~
				 Russia/Soviet Union~S. Korea~Saudi Arabia~Singapore~South Africa~Spain~
				 Sweden~Switzerland~Taiwan~Thailand~Turkey~United States~
				 Venezuela~Yugoslavia~Euro area~,
         ccode=ARG AUS AUT BEL BRA GBR 
               CAN CHL CHN COL CZE DNK 
			   FRA GER GRC NLD HKG HUN 
			   IDN IRL ISR ITA JPN MYS
			   MEX NZL PER PHL POL PRT 
			   RUS KOR SAU SGP ZAF ESP 
			   SWE CHE TWN THA TUR USA 
			   VEN YUG EUR);

  **Common Sample with PWT**;
  if yearp=2000;
run;


**Combine PWT and Big Mac**;
proc sort data=ppp_pwt; by year ccode; run;
proc sort data=ppp_bm; by yearp ccode; run;
data figure1;
  merge ppp_pwt ppp_bm(rename=(yearp=year));
  by year ccode;

  **Keep Only Obs with PWT and Big Mac Data Point**;
  if ppp_pwt ne . and ppp_bm ne .;
run;

**Print Data for Table 1 (Also used for Figure 1 Scatter Plot)**;
proc sort data=figure1; by year country; run;
proc print data=figure1;
  var country ppp_bm  ppp_pwt;
  format ppp_bm ppp_pwt 5.0;
  title "Figure 1 and Table 1";
  title2 "Table - Indicators of Purchasing Power Parity (2000)";
  title3 "Figure - PPP from the PWT and Big Mac (2000)";
run;
proc corr data=figure1 ;
  var ppp_bm;
  with ppp_pwt;
run;
/*PROC EXPORT DATA= WORK.FIGURE1
            OUTFILE= "d:\temp\figure1.xls" 
            DBMS=EXCEL2000 REPLACE;
RUN;*/


*----------------------------*;
* FIGURE 2                   *;
*----------------------------*;
/*goptions reset=all nocell targetdevice=winprtc gsfmode=replace
     hsize=7.5 in vsize=10 in gsflen=80
     ftitle="Helvetica/bold" ftext="Helvetica/regular" dashscale=.5 nodash htext=.10 in
     vpos=75 hpos=81 lfactor=3;

***PRODUCE THE CHARTS***;
symbol1 l=1 c=black w=1 i=join value=none;
symbol2 l=1 c=megr w=1 i=join value=none;

libname lib 'd:\temp';
proc greplay tc=lib.template nofs;
tdef _10 des='10 per page'
1/llx=0 lly=0
  ulx=0 uly=100
  urx=100 ury=100
  lrx=100 lry=0
2/llx=50 lly=0
  ulx=50 uly=100
  urx=150 ury=100
  lrx=150 lry=0
3/llx=0 lly=-18
  ulx=0 uly=82
  urx=100 ury=82
  lrx=100 lry=-18
4/llx=50 lly=-18
  ulx=50 uly=82
  urx=150 ury=82
  lrx=150 lry=-18
5/llx=0 lly=-36
  ulx=0 uly=64
  urx=100 ury=64
  lrx=100 lry=-36
6/llx=50 lly=-36
  ulx=50 uly=64
  urx=150 ury=64
  lrx=150 lry=-36
7/llx=0 lly=-54
  ulx=0 uly=46
  urx=100 ury=46
  lrx=100 lry=-54
8/llx=50 lly=-54
  ulx=50 uly=46
  urx=150 ury=46
  lrx=150 lry=-54
9/llx=0 lly=-72
  ulx=0 uly=28
  urx=100 ury=28
  lrx=100 lry=-72
10/llx=50 lly=-72
  ulx=50 uly=28
  urx=150 ury=28
  lrx=150 lry=-72
11/llx=0 lly=0
  ulx=0 uly=100
  urx=100 ury=100
  lrx=100 lry=0;
template _10;
list template;
quit;

%macro country(countryname=);
  %do i = 1 %to 10;
  %let c = %scan(&countryname,&i,"~");

proc gplot data=charts(where=(country="&c")) gout=plot;
  axis1
        order=(1986 to 2004 by 2)
        offset=(0)
        label=none
        length=2.5 in
        major=(h=.40 c=dagr)
		minor=none
        value=(h=.10 in);
  axis2 offset=(0)
        value=(h=.10 in)
        length=1.15 in  origin=(0.4,8.00) in
        major=(h=.75 c=dagr)
        minor=none
        label=none;
plot XRate*yearp=1 PPP*yearp=2/
	 overlay
     haxis=axis1
     vaxis=axis2
     frame
	 skipmiss
     name="_&i";
note j=l h=.16 in f="AvantGarde/regular" m=(0,69.5) "&c";
run;
quit;

%end;
%mend;
%country(countryname=Australia~Britain~Canada~Chile~Czech. Rep.~Denmark~Hong Kong~Hungary~Japan~Poland~);
proc gslide gout=plot name="_title";
  note h=14 pt f="AvantGarde/regular" m=(0.0,9.75) in "Figure 2";
  note h=14 pt f="AvantGarde/regular" m=(0.0,9.55) in "Absolute Purchasing Power Parity";
  note h=10 pt f="AvantGarde/regular" m=(0.0,9.40) in "Currency units / U.S. $";
  note h=8 pt c=black f="AvantGarde/regular" m=(3.0,0.30) in "Black line = Exchange Rate";
  note h=8 pt c=megr f="AvantGarde/regular" m=(3.0,0.15) in "Grey line = Implied PPP";
run;
quit;
proc greplay tc=lib.template template=_10 igout=plot nofs;
 treplay 1:_1 2:_2 3:_3 4:_4 5:_5 6:_6 7:_7 8:_8 9:_9 10:_10 11:_title;
 delete _all_;
run;
quit;*/

**Print Data for Figure 2 (Raw Data from Big Mac)**;
**  Australia, Britain, Canada, Chile, Czech, Denmark, Hong Kong, Hungary, Japan, Poland**;
proc sort data=charts out=figure2; by country year; run;
proc print data=figure2
		  (where=(country in("Australia","Britain","Canada",
							 "Chile","Czech. Rep.","Denmark",
							 "Hong Kong","Hungary","Japan","Poland"))) noobs; 
  var year xrate ppp;
  by country;
  title "Figure 2";
  title2 "Absolute Purchasing Power Parity";
  title3 "Currency units/ U.S. $";
run;
/*PROC EXPORT DATA= WORK.FIGURE2 
            OUTFILE= "d:\temp\figure2.xls" 
            DBMS=EXCEL2000 REPLACE;
RUN;*/

*----------------------------*;
* FIGURE 3                   *;
*----------------------------*;
**Create Big Mac PPP**;
data ppp_bm;
  set charts(keep=yearp country xrate ppp);
  ppp_bm =(ppp/xrate)*100;
run;

**Create Average PPP for All Countries in Big Mac**;
proc sort data=ppp_bm(rename=(yearp=year)); by year; run;
proc means data=ppp_bm mean noprint;
  var ppp_bm;
  by year;
  output out=ppp_avg mean=;
run;

**Create US$ Deviation**;
data ppp_avg;
  set ppp_avg(drop=_type_ _freq_);
  dev_bm=100-ppp_bm;
run;

**Read in TWEX Data (April Value)**
  Source: Federal Reserve Board of Governors
  fxtwb-Nominal Broad Trade-Weighted Exchange Value of the US$ (JAN 97=100)
  fxtwm-Nominal Trade-Weighted Exch Value of US$ vs Major Currencies (MAR 73=100);
PROC IMPORT 	
  OUT=twex
  DATAFILE= "d:\economis\pollard\extras\bigmac\twex_ann.xls" 	
  REPLACE
  DBMS=EXCEL2000;	
  RANGE=twex_ann; 	
  GETNAMES=yes;	
RUN;	
data twex(drop=sasdate);
  set twex(rename=(f1=sasdate) where=(sasdate ne .));
  sasdate=datepart(sasdate);
  year=year(sasdate);
run;

**Combine Avg. Big Mac PPP and Broad TWEX for Chart;
proc sort data=ppp_avg; by year; run;
proc sort data=twex; by year; run;
data figure3;
  merge ppp_avg twex;
  by year;
run;

**Print Data for Figure 3**;
proc print data=figure3 noobs; 
  var year dev_bm fxtwb;
  title "Figure 3";
  title2 "Average Deviation of US$ from PPP";
run;
/*PROC EXPORT DATA= WORK.FIGURE3 
            OUTFILE= "d:\temp\figure3.xls" 
            DBMS=EXCEL2000 REPLACE;
RUN;*/


*----------------------------------------------------*;
*--Table 2, Appendix Table 1, Shaded Insert 4      --*;
*----------------------------------------------------*;
**Create Data for Table 2 and Shaded Insert 4 (and Old Appendix Table 1)**;
data value(drop=ppp xrate);
  set charts(keep=year country xrate ppp);

  **Create Big Mac PPP**;
  Purchasing_Power = (ppp/xrate)*100;

  **For Foreign Currency: Overvalued, Undervalued or Parity**;
  if 99<=purchasing_power<=101 and purchasing_power ne . then value="Parity";
   else if purchasing_power<99 and purchasing_power ne . then value="Under";
   else if purchasing_power>101 and purchasing_power ne . then value="Over";
run;

*----------------------------------------------------*;
*--Shaded Insert 4                                 --*;
*----------------------------------------------------*;
**Print Data for Shaded Insert 4 Figure **;
proc sort data=value; by country; run;
proc print data=value(where=(country in("S. Korea","Argentina"))) noobs;
  var year country purchasing_power;
  title "Shaded Insert 4";
  title2 "PPP and Currency Crisis:  South Korea and Argentina";
run;

*----------------------------------------------------*;
*--Appendix Table 1                                --*;
*----------------------------------------------------*;
**Print Data for Appendix Table 1**;
proc transpose data=value out=table_a1f(drop=_name_); 
  var Purchasing_Power;
  by country;
  id year;
  idlabel year;
run;
PROC EXPORT DATA= WORK.table_a1f 
            OUTFILE= "d:\temp\table_a1a.xls" 
            DBMS=EXCEL2000 REPLACE;
RUN;
proc print data=table_a1f noobs; 
  var country _1986 _1987 _1988 _1989-_1993;
  title "Appendix Table 1";
  title2 "Purchasing Power Parity";
run;
proc print data=table_a1f noobs; 
  var country _1994-_1999;
run;
proc print data=table_a1f noobs; 
  var country _2000-_2003;
run;

proc sort data=value(where=(purchasing_power ne .)) out=table_a1count; by year country; run;
proc means data=value(where=(95<=purchasing_power<=105)) n;
var purchasing_power;
title "5%";
run;
proc means data=value(where=(90<=purchasing_power<=110)) n;
var purchasing_power;
title "10%";
run;

*----------------------------*;
* TABLE 2                    *;
*----------------------------*;
**Print Data for Table 2**;
proc sort data=value; by year; run;
proc transpose data=value out=table2; 
  var value;
  by year;
  id country;
  idlabel country;
run;
proc print data=table2 noobs; 
  var year China Indonesia Malaysia Philippines Thailand;
  title "Table 2 - Currency Valuation";
  title2 "Undervaluation or Overvaluation of Local Currency";
  title3 "Developing Countries-Asia";
run;
proc print data=table2 noobs; 
  var year Argentina Brazil Chile Colombia Mexico Peru Venezuela;
  title "Table 2 - Currency Valuation";
  title2 "Undervaluation or Overvaluation of Local Currency";
  title3 "Developing Countries-Latin America";
run;
proc print data=table2 noobs; 
  var year Saudi_Arabia South_Africa Turkey;
  title "Table 2 - Currency Valuation";
  title2 "Undervaluation or Overvaluation of Local Currency";
  title3 "Developing Countries-Other";
run;
proc print data=table2 noobs; 
  var year Czech__Rep_ Hungary Poland Russia_Soviet_Union;
  title "Table 2 - Currency Valuation";
  title2 "Undervaluation or Overvaluation of Local Currency";
  title3 "Countries in Transition";
run;
proc print data=table2 noobs; 
  var year Britain Canada Euro_Area France Germany_W__Germany Italy Japan;
  title "Table 2 - Currency Valuation";
  title2 "Undervaluation or Overvaluation of Local Currency";
  title3 "Major Advanced Economies";
run;
proc print data=table2 noobs; 
  var year Hong_Kong Singapore S__Korea Taiwan;
  title "Table 2 - Currency Valuation";
  title2 "Undervaluation or Overvaluation of Local Currency";
  title3 "Newly Industrialized Asian Economies";
run;
proc print data=table2 noobs; 
  var year Australia Austria Belgium Denmark Ireland Israel Holland New_Zealand Spain Sweden Switzerland;
  title "Table 2 - Currency Valuation";
  title2 "Undervaluation or Overvaluation of Local Currency";
  title3 "Other Advanced Economies";
run;


*----------------------------------------------------*;
*--Appendix Table 2                                --*;
*----------------------------------------------------*;
proc sort data=charts; by country year; run;
data table_a2(drop=PPP BMDollar lBMLocal lXRate BMLocal BMLocal_c XRate BMUS BMUS_c lcountry);
  set charts;

**Inflation Differential**;
  **Change in US$ Price**;
  BMUS_c = (log(BMUS)-log(lag(BMUS)))*100;
    if year=1986 then BMUS_c=.;
  **Change in Local Currency Price**;
  lBMLocal=lag(BMLocal);
  if BMLocal ne . and lBMLocal ne . then BMLocal_c = (log(BMLocal)-log(lBMLocal))*100;
    if year=1986 then BMLocal_c=.;
  **Final Differential**;
  InfDiff=BMLocal_c-BMUS_c;
**Cumulative Inflation Differential**;
  lcountry=lag(country);
  retain cuminf cuminf;
    if country ne lcountry then cuminf=0;
      else if country=lcountry then cuminf=sum(cuminf,infdiff);
**Exchange Rate Change**;
  lXRate=lag(XRate);
  if XRate ne . and lXRate ne . then XRate_c = (log(XRate)-log(lXRate))*100;
    if year=1986 then XRate_c=.;
**Cumulative Exchange Rate Change**;
  retain cumx cumx;
    if country ne lcountry then cumx=0;
      else if country=lcountry then cumx=sum(cumx,xrate_c);
run;
data table_a2;
  set table_a2;
  if infdiff=. then cuminf=.;
  if xrate_c=. then cumx=.;
run;

proc transpose data=table_a2 out=table_a2f;
  var InfDiff XRate_c cuminf cumx;
  by country;
  id year;
  idlabel year;
run;
data table_a2f(drop=lcountry _name_);
  length _name_ row $35.;
  set table_a2f(where=(country ne "United States"));
  lcountry=lag(country);
  if country=lcountry then country=" ";

  if _name_="XRate_c" then row="Change in exchange rate";
  if _name_="InfDiff" then row="Inflation differential";
  if _name_="cuminf" then row="Cumulative inflation differential";
  if _name_="cumx" then row="Cumulative change in exchange rate";
run;
/*
**Print Data for Appendix Table 2**;
proc print data=table_a2f noobs; 
  var country row _1986-_1990;
  format _1986-_1990 5.0;
  title "Appendix Table 2";
  title2 "Relative Big Mac Purchasing Power Parity (%)";
run;
proc print data=table_a2f noobs; 
  var country row _1991-_1996;
  format _1991-_1996 5.0;
run;
proc print data=table_a2f noobs; 
  var country row _1997-_2003;
  format _1997-_2003 5.0;
run;
*/

*----------------------------*;
* FIGURE 4                   *;
*----------------------------*;
**Create Line in Figure 4                   **;
**  Top Panel:  Australia, Canada, Britain  **;
**  Bottom Panel:  Denmark, Japan, Hong Kong**;
data figure4; 
  set table_a2(where=(country in ("Australia","Canada","Britain","Denmark","Japan","Hong Kong")));
  **Inflation Differential - Exchange Rate Change**;
  **  (See above for calcs.**;
  plotline=infdiff-xrate_c;
run;
proc sort data=figure4; by year; run;
proc transpose data=figure4 out=figure4f;
  var plotline;
  by year;
  id Country;
  idlabel Country;
run;
**Print Out Data for Figure 4**;
proc print data=figure4f noobs; 
  var year Australia Canada Britain Denmark Hong_Kong Japan;
  title "Figure 4";
  title2 "Relative Purchasing Power Parity";
  title3 "Inflation Differential Less Exchange Rate Change (percent)";
run;
/*PROC EXPORT DATA= WORK.FIGURE4F 
            OUTFILE= "d:\temp\figure4.xls" 
            DBMS=EXCEL2000 REPLACE;
RUN;*/


*----------------------------*;
* FIGURE 5                   *;
*----------------------------*;
**Keep Only Countries in PWT and UBS**;
**  CZE and EGY = no UBS Data       **;
**  CYP, TWN, ARE, BHR = no PWT Data**;
/*2000 Countries
data figure5(keep=ccode year p_pwt cgdp_pwt);
  merge pwt (where=(ccode in ("ARG","AUS","BRA","GBR",
               "CAN","CHL","CHN","COL","CZE","DNK",
			   "FRA","GER","GRC","HKG","HUN",
			   "IDN","ISR","ITA","JPN","MYS",
			   "MEX","NZL","PHL","POL",
			   "RUS","KOR","SGP","ZAF","ESP",
			   "SWE","CHE","THA","TUR","USA")
  			or ccode in("AUT","BEL","CYP","EGY","FIN",
			   "IND","IRL","KEN","LUX","NLD",
			   "NOR","PAN","PRT","TWN","ARE",
			   "VEN","BHR")))
		pwt_us;
*/
*2003 Countries;
data figure5(keep=ccode year p_pwt cgdp_pwt);
  merge pwt (where=(ccode in ("ARG","AUS","BRA","GBR",
               "CAN","CHL","CHN","COL","CZE","DNK",
			   "HKG","HUN",
			   "IDN","JPN","MYS",
			   "MEX","NZL","PER","PHL","POL",
			   "RUS","KOR","SGP","ZAF",
			   "SWE","CHE","TWN","THA","TUR","USA","VEN",/*"EUR"*/)
  			or ccode in("AUT","BEL","BGR","CYP",
				"EST","FIN","FRA","GER","GRC","IND","IRL","ISR","ITA","KEN",
				"LVA","LTU","LUX","NLD","NGA","NOR","PAK","PAN",
				"PRT","ROM","SVK","SVN","ESP",
				"ARE","UKR","BHR")))
		pwt_us;
  by year;
  if year=2000;
  p_pwt=(p/p_us)*100;
  cgdp_pwt=(cgdp/cgdp_us)*100;
run;

**Print Out Data for Figure 5**;
proc print data=figure5 noobs; 
  var year ccode p_pwt cgdp_pwt;
  title "Figure 5 (Top Panel)";
  title2 "Income and Prices";
  title3 "Per Capita Income and Prices (PWT)";
run;
/*PROC EXPORT DATA= WORK.FIGURE5
            OUTFILE= "d:\temp\figure5.xls" 
            DBMS=EXCEL2000 REPLACE;
RUN;*/
*Footnote 18*;
proc reg data=figure5;
model p_pwt=cgdp_pwt;
run;
quit;


*----------------------------*;
* Shaded Insert 3            *;
*----------------------------*;
data BMGer(keep=year bmger);
  set charts(rename=(BMLocal=BMGer) where=(country="Germany/W. Germany"));
run;
data XRateGer(keep=year xrateger);
  set charts(rename=(xrate=XRateGer) where=(country="Germany/W. Germany"));
run;

proc sort data=charts; by year; run;
data insert3(keep=year country deviation);
  merge charts(keep=year country bmlocal xrate 
			   where=(country in ("Britain","Denmark","France",
			    				  "Italy","Spain","Sweden"))) 
		BMGer XRateGer;
  by year;

  PRGer=BMLocal/BMGer;
  Deviation=((PRGer/(XRate*(1/XRateGer))-1)*100);
run;

proc transpose data=insert3 out=insert3_dm(drop=_name_);
  var deviation;
  by year;
  id country;
  idlabel country;
run;
**Print Out Data for Shaded Insert 3**;
proc print data=insert3_dm noobs; 
  title "Shaded Insert 3";
  title2 "Deviation from PPP - Relative to German Mark";
  title3 "  Top:  France, Spain, Italy";
  title4 "  Bottom:  Britain, Denmark, Sweden";
run;